home *** CD-ROM | disk | FTP | other *** search
/ MACD 5 / MACD 5.bin / internet / yam_i_dodatki / yamaminetftp / aminetftp.yam < prev   
Text File  |  1997-09-09  |  9KB  |  260 lines
  1. /* $VER: AminetFTP.yam 2.6 (09 SEP 97)
  2. ** by Charles Patterson <midian@azstarnet.com>
  3. ** http://www.azstarnet.com/~midian
  4. **
  5. ** Localization by Marc Hemes <marc.hemes@braunschweig.netsurf.de
  6. **
  7. ** Description: This script finds your "Today's Aminet Upload" email in
  8. **              YAM, lists the files so you can choose which ones you want
  9. **              to download, then uses AmFTP to download the selected files.
  10. **
  11. ** Requirements: YAM 1.3.4 (© 1995-96 Marcel Beck)
  12. **               TCP/IP Stack
  13. **               rexxreqtools.library 1.3 (© 1992-94 Rafael D'Halleweyn)
  14. **               AmFTP 1.75 (© 1995-97 Mathias Michler)
  15. **
  16. ** Instructions: Send email to listproc@mail.wustl.edu with the body:
  17. **                              SUBSCRIBE aminet-daily Your Name
  18. **                           or SUBSCRIBE aminet-weekly Your Name
  19. **               Copy this file to YAM:Rexx/
  20. **               Set FILES to the number of files you want listed at a time
  21. **               Open the YAM:.config file and add this line:
  22. **                              RexxMenu1 = YAM:Rexx/AminetFTP.yam
  23. **               Change the AMFTP, AMINET and LOCALDIR settings in script
  24. **               Download your email then run this script from the YAM
  25. **                  ARexx menu.
  26. **
  27. ** --- Files listed: --- */
  28. FILES = 10
  29.  
  30. /* --- Path to run AmFTP: --- */
  31. AMFTP="DH2:Applications/AmFTP/AmFTP"
  32.  
  33. /* --- Local Aminet Site: --- */
  34. AMINET="wuarchive.wustl.edu"
  35.  
  36. /* --- Local directory Site: --- */
  37. LOCALDIR="DH2:Lookat"
  38.  
  39. today = "Today's Aminet "
  40. weekly = "This week's Ami"
  41.  
  42. OPTIONS RESULTS
  43. ADDRESS YAM
  44.  
  45. IF ~SHOW('L','rexxsupport.library') THEN
  46.     ADDLIB('rexxsupport.library',0,-30,0)
  47.  
  48. IF ~SHOW('L','rexxreqtools.library') THEN
  49.     ADDLIB('rexxreqtools.library',0,-30,0)
  50.  
  51. NL = '0A'x
  52.  
  53. IF OPEN('localeprefs','ENV:sys/locale.prefs','R') THEN DO
  54.     language = SUBSTR(READCH('localeprefs', 113), 83, 29)
  55.     language = SUBSTR(language, 1, POS(D2C(0), language) - 1)
  56.     CLOSE('localeprefs')
  57. END
  58.  
  59. SELECT
  60.     WHEN language = 'deutsch' THEN DO  /* german text */
  61.         MSG_NOMAIL        = "Keine E-Mails im Ordner !"
  62.         MSG_ASKCHECK      = "Welche möchten Sie prüfen ?"
  63.         MSG_ASKCHECK_GAD  = "Heu_te|_Woche|Alle tä_glichen|Alle wöch_entlichen|_Alle|Abbru_ch"
  64.         MSG_MAILNOTFOUND  = "E-Mails mit Aminet-Uploads nicht gefunden !"
  65.         MSG_LISTFILES     = "Dateien aus welchen E-Mails auflisten ?"
  66.         MSG_LISTFILES_GAD = "Au_sgewählte|_Andere"
  67.         MSG_FILES         = "Dateinummern eingeben (z.B. 1 2 5)"
  68.         MSG_FILES_GAD     = "_Ok|_Fertig|_Abbruch|_Zurück|_Weiter"
  69.         MSG_README        = "Möchten Sie für jede Datei auch auch die zugehörigen .readme-Dateien ? "
  70.         MSG_README_GAD    = "_Ja|_Nein"
  71.     END
  72.     WHEN language = 'français' THEN DO  /* french text */
  73.         MSG_NOMAIL        = "Pas de messages dans ce dossier !"
  74.         MSG_ASKCHECK      = "Souhaitez-vous rechercher les nouveautés dans les messages de ?"
  75.         MSG_ASKCHECK_GAD  = "_Aujourd'hui|La _semaine|Tous les _jours|Toute _les semaines|_Tous|_Annuler"
  76.         MSG_MAILNOTFOUND  = "Message des nouveautés sur Aminet pas trouvé !"
  77.         MSG_LISTFILES     = "Lister les nouveautés dans les messages"
  78.         MSG_LISTFILES_GAD = "_Sélectionnés|_Autres"
  79.         MSG_FILES         = "Entrez les numéros des fichiers (par ex. 1 2 5)"
  80.         MSG_FILES_GAD     = "_Ok|_Terminé|_Annuler|_Revenir|_Prochain"
  81.         MSG_README        = "Souhaitez-vous recevoir les fichiers .readme également ?"
  82.         MSG_README_GAD    = "_Oui|_Non"
  83.     END
  84.     OTHERWISE DO /* english text */
  85.         MSG_NOMAIL        = "No email in folder!"
  86.         MSG_ASKCHECK      = "Do you wish to check"
  87.         MSG_ASKCHECK_GAD  = "_Today's|_Week's|All _dailys|All w_eeklys|_All|_Cancel"
  88.         MSG_MAILNOTFOUND  = "Aminet Uploads email not found!"
  89.         MSG_LISTFILES     = "List files in:"
  90.         MSG_LISTFILES_GAD = "_Selected|_Other"
  91.         MSG_FILES         = "Enter filenumbers (ie. 1 2 5)"
  92.         MSG_FILES_GAD     = "_Ok|_Finished|_Abort|_Back|_Next"
  93.         MSG_README        = "Do you want each file's .readme as well?"
  94.         MSG_README_GAD    = "_Yes|_No"
  95.     END
  96. END
  97.  
  98. INFO SCREEN
  99. pubscreen = result
  100. GETFOLDERINFO MAX
  101. entries=result
  102. IF entries=0 THEN
  103.     DO
  104.         test=RTEZREQUEST(MSG_NOMAIL,"_Ok",,"rt_pubscrname="pubscreen)
  105.         EXIT
  106.     END
  107.  
  108. lfi = 0
  109. t = 0
  110. checkn = 0
  111. filename. = ''
  112. GETMAILINFO SUBJECT
  113. sub = LEFT(RESULT,15)
  114. IF sub = today | sub = weekly THEN
  115.     DO
  116.         test=RTEZREQUEST(MSG_LISTFILES,MSG_LISTFILES_GAD,,"rt_pubscrname="pubscreen)
  117.         lfi = rtresult
  118.     END
  119. IF lfi THEN
  120.     DO
  121.         t = 1
  122.         GETMAILINFO FILE
  123.         filename.1 = RESULT
  124.     END
  125. ELSE
  126.     DO
  127.         test=RTEZREQUEST(MSG_ASKCHECK,MSG_ASKCHECK_GAD,,"rt_pubscrname="pubscreen)
  128.         checkn = rtresult
  129.         IF checkn = 0 THEN EXIT
  130.         IF checkn = 1 | checkn = 3 THEN check = today
  131.         IF checkn = 2 | checkn = 4 THEN check = weekly
  132.         DO n = entries-1 TO 0 BY -1
  133.             SETMAIL n
  134.             GETMAILINFO SUBJECT
  135.             sub = LEFT(RESULT,15)
  136.             IF checkn = 5 THEN
  137.                 DO
  138.                     IF sub = today | sub = weekly THEN
  139.                         DO
  140.                             t = t + 1
  141.                             GETMAILINFO FILE
  142.                             filename.t = RESULT
  143.                         END
  144.                     END
  145.             ELSE
  146.                 IF sub = check THEN
  147.                     DO
  148.                         t = t + 1
  149.                         GETMAILINFO FILE
  150.                         filename.t = RESULT
  151.                     END
  152.         END
  153.     END
  154.  
  155. IF t = 0 THEN
  156.     DO
  157.         test=RTEZREQUEST(MSG_MAILNOTFOUND,"_Ok",,"rt_pubscrname="pubscreen)
  158.         EXIT
  159.     END
  160.  
  161. IF checkn < 3 THEN t = 1
  162.  
  163. DO mail = 1 to t
  164.     line. = ''
  165.     ADDRESS COMMAND 'COPY 'filename.mail' TO T:FTPMail.rct'
  166.     OPEN('recent','T:FTPMail.rct','R')
  167.  
  168.     DO UNTIL LEFT(READLN('recent'),3) = '|--'
  169.     END
  170.  
  171.     i=0
  172.     DO WHILE ~EOF('recent')
  173.         i=i+1
  174.         line.i=READLN('recent')
  175.         IF LEFT(line.i,1) = '|' THEN BREAK
  176.         IF STRIP(line.i) = '' THEN i=i-1
  177.     END
  178.     CLOSE('recent')
  179.  
  180.     c = 0
  181.     w = i%FILES
  182.     IF i//FILES >0 THEN w = w + 1
  183.  
  184.     DO n = 1 to w
  185.         DO f = n*FILES-(FILES-1) to n*FILES
  186.             PARSE VAR line.f file.f dir.f size.f '+' desc.f
  187.             file.f = LEFT(file.f,18,' ')
  188.             dir.f = LEFT(dir.f,10,' ')
  189.             size.f = RIGHT(size.f,4,' ')
  190.             desc.f = LEFT(desc.f,37,)
  191.         END
  192.  
  193.         reqstr = ''
  194.         DO x = f-FILES to f-1
  195.             y=x
  196.             if y<10 then y=' '||y
  197.             reqstr =  reqstr || y'. 'file.x' 'dir.x' 'size.x' 'desc.x||NL
  198.         END
  199.         input = RTGETSTRING(,reqstr,MSG_FILES,MSG_FILES_GAD,"rt_pubscrname="pubscreen)
  200.         SELECT
  201.             WHEN rtresult = 2 THEN BREAK
  202.             WHEN rtresult = 3 THEN EXIT
  203.             WHEN rtresult = 4 THEN DO
  204.                 n = n - 2
  205.                 IF n < 0 then n = 0
  206.             END
  207.             OTHERWISE DO WHILE input ~= ''
  208.                 c = c+1
  209.                 PARSE VAR input filenum.c input
  210.                 j = filenum.c
  211.                 IF STRIP(file.j) = '' THEN c = c-1
  212.             END
  213.         END
  214.     END
  215.  
  216.     close = 0
  217.     IF c > 0 THEN
  218.         DO
  219.             test=RTEZREQUEST(MSG_README,MSG_README_GAD,,"rt_pubscrname="pubscreen)
  220.             read = rtresult
  221.             IF ~SHOW('P',AMFTP.1) THEN
  222.                 DO
  223.                     ADDRESS COMMAND RUN AMFTP
  224.                     ADDRESS COMMAND WAITFORPORT AMFTP.1
  225.                     close=1
  226.                 END
  227.  
  228.             ADDRESS 'AMFTP.1'
  229.             CALL OPENPORT("AMFTP-RESULT.1")
  230.             CHANGELOCALDIR LOCALDIR
  231.             CONNECTHOST AMINET
  232.             WAITACTION "AMFTP-RESULT.1"
  233.             CALL WAITPKT "AMFTP-RESULT.1"
  234.  
  235.             DO mc = 1 to c
  236.                 d = filenum.mc
  237.                 dir = STRIP(dir.d)
  238.                 file = "/pub/aminet/"dir"/"file.d
  239.                 RECEIVE file
  240.                 WAITACTION "AMFTP-RESULT.1"
  241.                 CALL WAITPKT "AMFTP-RESULT.1"
  242.                 IF read THEN
  243.                     DO
  244.                         lgt = LENGTH(COMPRESS(file))-3
  245.                         filer = LEFT(file,lgt)||"readme"
  246.                         RECEIVE filer
  247.                         WAITACTION "AMFTP-RESULT.1"
  248.                         CALL WAITPKT "AMFTP-RESULT.1"
  249.                     END
  250.             END
  251.             'CLOSE'
  252.             CALL CLOSEPORT "AMFTP-RESULT.1"
  253.             IF close THEN QUIT
  254.         END
  255.  
  256. END
  257. ADDRESS COMMAND 'DELETE T:FTPMail.*'
  258. EXIT
  259.  
  260.